Views

Histats

Vitrine

VBA Outlook 2010 - Visualizando as propriedades do Servidor Exchange - View Exchange Server Properties




Este exemplo demonstra as propriedades novas e aprimoradas que fornecem informações sobre o Servidor Exchange para a conta conectada no Microsoft Outlook 2010.

Esta amostra pode ser incorporado diretamente em seu código.

O Outlook 2010 fornece suporte para termos contas de vários Servidores Exchange em um único perfil.

A coleção de novas contas fora da Session Object fornece acesso aos objetos de Conta. Por sua vez, esses casos foram aprimorados com novas propriedades que fornecem informações sobre o Servidor Exchange a qual a conta está conectada. 

Para testar este código, você precisa ao menos de uma conta no Exchange (duas ou mais é preferido).

Abra o editor de VBA e cole o código no módulo ThisOutlookSession existente.

Abra a janela de visualização imediata e com o cursor dentro deste método, pressione F5.

Sub GetMultipleExchangeAccounts() 
     
    Dim host As Outlook.Application 
    Set host = ThisOutlookSession.Application 
         
    ' Check for Outlook 2010 
    If Left(host.Version, 2) = "14" Then 
        Dim acct As Outlook.Account 
        Dim col As New VBA.Collection 
         
        ' Enumerate the list of accounts looking for 
        ' those that are Exchange Server accounts 
        ' If an account is found, add it to a 
        ' collection to be used later. 
        For Each acct In host.Session.Accounts 
            If acct.AccountType = olExchange Then 
                col.Add acct 
            End If 
        Next 
         
        ' Did the code find any accounts of the type olExchange? 
        If col.Count > 0 Then 
            For Each acct In col 
                Debug.Print "ExchangeMailboxServerName: " & acct.ExchangeMailboxServerName 
                Debug.Print "  AutoDiscoverConnectionMode: " & acct.AutoDiscoverConnectionMode 
                ' The following property returns a fairly large XML document 
                ' uncomment if you wish to see this data. 
                ' Debug.Print "  AutoDiscoverXml: " & acct.AutoDiscoverXml 
                Debug.Print "  CurrentUser: " & acct.CurrentUser 
                Debug.Print "  DeliveryStore: " & acct.DeliveryStore 
                Debug.Print "  ExchangeConnectionMode: " & acct.ExchangeConnectionMode 
                Debug.Print "  ExchangeMailboxServerVersion: " & acct.ExchangeMailboxServerVersion 
            Next 
        Else 
            MsgBox "You do not have any accounts configured to use an Exchange Server." 
        End If 
    Else 
        MsgBox "This code only works with Outlook 2010." 
    End If 
End Sub


Tags: VBA, Outlook, Exchange, Server, Properties, Outlook.ExchangeAccounts



✔ VBA Brazil®

✔ VBA Brazil®
brazilsalesforceeffectiveness@gmail.com
Related Posts Plugin for WordPress, Blogger...
diHITT - Notícias